home *** CD-ROM | disk | FTP | other *** search
/ Aminet 48 / Aminet 48 (2002)(GTI - Schatztruhe)[!][Apr 2002].iso / Aminet / comm / tcp / muinlmiamipane.lha / MUI_NL.MiamiPanel / Install < prev   
Encoding:
Text File  |  2002-01-25  |  6.0 KB  |  166 lines
  1. ; $VER: MUI_NL.MiamiPanel_Install 4.6 (22.1.2002)
  2.  
  3. (procedure P_SetMessages
  4.  
  5.     (if (= "italiano" @language)
  6.         (
  7.             (set #WhatInstallPromptMsg          "Cosa vuoi installare?")
  8.             (set #WhatInstallHelpMsg            "Scegli cosa vuoi installare:\nLibreria - la libreria MUI_NL.MiamiPanel\nClassiMUI - alcune classi MUI\nDocumentazione - la documentazione di MUI_NL.MiamiPanel in formato AmigaGuide")
  9.  
  10.             (set #WhatInstallLibraryMsg         "Libreria")
  11.             (set #WhatInstallMCCsMsg            "Classi MUI")
  12.             (set #WhatInstallDocumentationMsg   "Documentazione")
  13.  
  14.             (set #AskLibDirPromptMsg            "Scegli la directory dove installare la libreria")
  15.             (set #AskLibDirHelpMsg              "Nella directory che sceglierai, verrà copiata la libreria MUI_NL.MiamiPanel. Nota che deve essere MIAMI:LIBS")
  16.  
  17.             (set #AskMCCsDirPromptMsg           "Scegli la directory dove installare alcuni classi MUI")
  18.             (set #AskMCCsDirHelpMsg             "Nella directory che sceglierai, verranno copiate alcune classi MUI. Ovviamente la directory scelta, dovrà essere nell'assegnamento logico LIBS:")
  19.  
  20.             (set #AskGuideDirPromptMsg          "Scegli la directory dove installare la documentazione di MUI_NL.MiamiPanel")
  21.             (set #AskGuideDirHelpMsg            "Nella directory che sceglierai, verrà copiata la documentazione di MUI_NL.MiamiPanel in formato AmigaGuide. Per poter utilizzare lo help online, la guida deve essere installata in MIAMI:")
  22.  
  23.             (set #CopyingLibMsg                 "Sto copiando la libreria...")
  24.             (set #CopyingMCCsMsg                "Sto copiando le classi MUI...")
  25.             (set #CopyingGuideMsg               "Sto copiando la documentazione...")
  26.         )
  27.         (
  28.             (set #WhatInstallPromptMsg          "What do you want to install?")
  29.             (set #WhatInstallHelpMsg            "Choose what you want to install:\nLibrary - MUI_NL.MiamiPanel library\nMUI classes - some MUI custom classes\nDocumentation - MUI_NL.MiamiPanel documentation in AmigaGuide format\n")
  30.  
  31.             (set #WhatInstallLibraryMsg         "Library")
  32.             (set #WhatInstallMCCsMsg            "MUI classes")
  33.             (set #WhatInstallDocumentationMsg   "Documentation")
  34.  
  35.             (set #AskLibDirPromptMsg            "Select the drawer where you want to copy MUI_NL.MiamiPanel library")
  36.             (set #AskLibDirHelpMsg              "In the drawer you supply here, there will be installed MUI_NL.MiamiPanel library. Note that this must be Miami:LIBS.")
  37.  
  38.             (set #AskMCCsDirPromptMsg           "Select the drawer where you want to copy some MUI classes")
  39.             (set #AskMCCsDirHelpMsg             "In the drawer you supply here, there will be installed some MUI classes. This drawer MUST BE in your LIBS: assignment")
  40.  
  41.             (set #AskGuideDirPromptMsg          "Select the drawer where you want to install MUI_NL.MiamiPanel AmigaGuide documentation")
  42.             (set #AskGuideDirHelpMsg            "In the drawer you supply here, there will be installed the MUI_NL.MiamiPanel documentation in AmigaGuide format. To use the online help, the guide must be installed in MIAMI:")
  43.  
  44.             (set #CopyingLibMsg                 "Copying or Updating library")
  45.             (set #CopyingMCCsMsg                "Copying or Updating MUI classes")
  46.             (set #CopyingGuideMsg               "Copying documentation")
  47.         )
  48.     )
  49. )
  50.  
  51. (procedure P_ChooseWhatIstall
  52.     (set #WhatInstall
  53.         (askoptions (prompt #WhatInstallPromptMsg)
  54.                     (help #WhatInstallHelpMsg)
  55.                     (choices #WhatInstallLibraryMsg #WhatInstallMCCsMsg #WhatInstallDocumentationMsg)
  56.         )
  57.     )
  58. )
  59.  
  60. (procedure P_AskLibDir
  61.     (set #libDir
  62.         (askdir
  63.             (prompt #AskLibDirPromptMsg)
  64.             (help #AskLibDirHelpMsg)
  65.             (default "MIAMI:LIBS")
  66.         )
  67.     )
  68. )
  69.  
  70. (procedure P_AskMCCsDir
  71.     (set #MCCsDir
  72.         (askdir
  73.             (prompt #AskMCCsDirPromptMsg)
  74.             (help #AskMCCsDirHelpMsg)
  75.             (default "MUI:LIBS/MUI/")
  76.         )
  77.     )
  78. )
  79.  
  80. (procedure P_AskGuideDir
  81.     (set #guideDir
  82.         (askdir
  83.            (prompt #AskGuideDirPromptMsg)
  84.            (help #AskGuideDirHelpMsg)
  85.            (default "MIAMI:")
  86.         )
  87.     )
  88. )
  89.  
  90. (procedure P_CopyLib
  91.     (working #CopyingLibMsg)
  92.     (set #localLibDir (tackon #source-dir "LIBS/"))
  93.     (foreach #localLibDir "#?"
  94.         (copylib
  95.             (source (tackon #localLibDir @each-name))
  96.             (dest #libDir)
  97.         )
  98.     )
  99. )
  100.  
  101. (procedure P_CopyMCCs
  102.     (working #CopyingMCCsMsg)
  103.     (set #localMCCSDir (tackon #source-dir "MUI/"))
  104.     (foreach #localMCCsDir "#?"
  105.         (copylib
  106.             (source (tackon #localMCCsDir @each-name))
  107.             (dest #MCCsDir)
  108.         )
  109.     )
  110. )
  111.  
  112. (procedure P_CopyDocs
  113.     (working #CopyingGuideMsg)
  114.     (set #docsDir (tackon #source-dir (tackon "DOCS" @language)))
  115.     (if (= (exists #docsDir) 0)
  116.         (set #docsDir (tackon #source-dir "DOCS/english"))
  117.     )
  118.     (copyfiles
  119.         (source #docsDir)
  120.         (dest #guideDir)
  121.         (optional force askuser)
  122.         (all)
  123.     )
  124. )
  125.  
  126. (procedure P_CopyCatalogs
  127.     (set #catSourceDir (tackon #source-dir (tackon "Catalogs" @language)))
  128.     (set #catDestDir (tackon "Locale:" (tackon "Catalogs" @language)))
  129.     (if (= (and (= (exists (#catSourceDir)) 2) (= (exists (#catDestDir)) 2)) 1)
  130.         (foreach #catSourceDir "#?"
  131.             (copylib
  132.                 (source (tackon #catSourceDir @each-name))
  133.                 (dest #catDestDir)
  134.             )
  135.         )
  136.     )
  137. )
  138.  
  139. (set @default-dest "MIAMI:LIBS")
  140. (set #source-dir (if (= 1 (exists @icon)) (pathonly (expandpath @icon)) (expandpath @icon)))
  141.  
  142. (P_SetMessages)
  143.  
  144. (complete 0)
  145.  
  146. (P_ChooseWhatIstall)
  147.  
  148. (if (= 0 #WhatInstall) (exit))
  149. (if (BITAND #WhatInstall  1)  (P_AskLibDir))
  150. (if (BITAND #WhatInstall  2)  (P_AskMCCsDir))
  151. (if (BITAND #WhatInstall  4)  (P_AskGuideDir))
  152.  
  153. (if (BITAND #WhatInstall  1)
  154.     (
  155.         (P_CopyLib)
  156.         (P_CopyCatalogs)
  157.     )
  158. )
  159. (complete 35)
  160.  
  161. (if (BITAND #WhatInstall  2)  (P_CopyMCCs))
  162. (complete 80)
  163.  
  164. (if (BITAND #WhatInstall  4)  (P_CopyDocs))
  165. (complete 100)
  166.